Excel Templates

Ice Hockey World Cup 2009 Interactive Schedule

Excel Trick — Wed, 06 May 2009 11:00:40 +0000

Ice Hockey World Cup 2009 Schedule in Excel incorporates a full calendar of all the finals of a 2009 Hockey World Cup Tournament that will take place on April 24 - May 10 in Zurich and Berne, Switzerland. As always, this product comes free of charge for your personal enjoyment.

Track Hockey World Cup 2009 Schedule with an advanced tool! Available in a form of an Excel spreadsheet, Ice Hockey World Cup 2009 Schedule helps you track the games by automatically calculating the performance of every team. Hockey World Cap 2009 Schedule helps you track teams that make it to the quarterfinal, semifinal and final without the use of macros. Just fill in the cells with the number of pucks scored by each team, and specify whether the game ended in regular time or overtime, and Track Hockey World Cap 2009 Schedule will calculate the results automatically, helping you to figure out the advancements made by each team. With all the technology available at your fingertips, you can make informed predictions, make better bets and amaze your friends with your knowledge of Hockey World Cup 2009.

Track Hockey World Cup 2009 Schedule is absolutely free for personal use. The calendar is available in English, German, French, Spanish, and Russian, and supports different time zones to help you figure out when exactly a match happens in your local time. Ice Hockey World Cup 2009 Schedule in Excel does not use Excel macros, and works safely and securely in every version of Microsoft Excel available.

Download World Cup 2009 Schedule

Interactive schedule (flash version)

UPDATE: Schedule has been fixed. Please download the latest version.
We apologize for the inconvenience

Using InputBox Method in Excel VBA

Excel Trick — Fri, 10 Apr 2009 13:45:08 +0000

You can recieve a simple information from user using Message Box in your Excel VBA code: Yes / No / Cancel etc.

But to gather more specific information (formula, number, text, logical value or cell reference) from a user you need Application.InputBox method:

InputBox(Prompt[,Title][,Default][,x][,y][,HelpFile][,HelpContextId][,Type])

where Type specifies the return data type:

Type Values
0	Formula
1	Number
2	Text (String)
4	Logical value (True or False)
8	Cell reference (Range object)
16	Error value
64	Array of values

Example: Using InputBox method in Excel

Sub TestInputBox()
    Dim myRange As Range
 
    Set myRange = Application.InputBox(Prompt:= _
        "Please Select a Range", _
        Title:="InputBox Method", Type:=8)
 
    If myRange Is Nothing Then
        ' Range is blank
    Else
        myRange.Select
    End If
End Sub

Custom Message Box Buttons using Hooking in Excel VBA

Excel Trick — Thu, 09 Apr 2009 14:43:07 +0000

Q. How can I change the button caption for the Message Box (MsgBox)?

A. You need to use Windows Hooking API in your Excel VBA:

You must create a CBT hook
Run a Message Box with CBT hook
Catch a HCBT_ACTIVATE message in the Hook procedure
Set new cputions for the buttons using the SetDlgItemText function
(example below changes “Yes” and “No” captions to smiles: “:-)” and “:-(” )
Release the CBT hook

Example: Change Button Captions for Message Box using VBA in Excel:

Option Explicit
 
' Import
Private Declare Function GetCurrentThreadId Lib "kernel32" () As Long
 
Private Declare Function SetDlgItemText Lib "user32" _
    Alias "SetDlgItemTextA" _
    (ByVal hDlg As Long, _
     ByVal nIDDlgItem As Long, _
     ByVal lpString As String) As Long
 
Private Declare Function SetWindowsHookEx Lib "user32" _
    Alias "SetWindowsHookExA" _
    (ByVal idHook As Long, _
     ByVal lpfn As Long, _
     ByVal hmod As Long, _
     ByVal dwThreadId As Long) As Long
 
Private Declare Function UnhookWindowsHookEx Lib "user32" _
    (ByVal hHook As Long) As Long
 
' Handle to the Hook procedure
Private hHook As Long
 
' Hook type
Private Const WH_CBT = 5
Private Const HCBT_ACTIVATE = 5
 
' Constants
Public Const IDOK = 1
Public Const IDCANCEL = 2
Public Const IDABORT = 3
Public Const IDRETRY = 4
Public Const IDIGNORE = 5
Public Const IDYES = 6
Public Const IDNO = 7
 
Public Sub MsgBoxSmile()
    ' Set Hook
    hHook = SetWindowsHookEx(WH_CBT, _
                             AddressOf MsgBoxHookProc, _
                             0, _
                             GetCurrentThreadId)
 
    ' Run MessageBox
    MsgBox "Smiling Message Box", vbYesNo, "Message Box Hooking"
End Sub
 
Private Function MsgBoxHookProc(ByVal lMsg As Long, _
                                ByVal wParam As Long, _
                                ByVal lParam As Long) As Long
 
    If lMsg = HCBT_ACTIVATE Then
        SetDlgItemText wParam, IDYES, ":-)"
        SetDlgItemText wParam, IDNO, ":-("
 
        ' Release the Hook
        UnhookWindowsHookEx hHook
    End If
 
    MsgBoxHookProc = False
End Function

Define a Position of MessageBox using VBA in Excel

Excel Trick — Thu, 09 Apr 2009 09:26:29 +0000

Typical MsgBox pops-up in the center of the screen. You can change MsgBox’s position using a Hooking API in your VBA code:

You must create a CBT hook
Run a Message Box with CBT hook
Catch a HCBT_ACTIVATE message in the Hook procedure
Set new position using the SetWindowPos function
Release the CBT hook

Example: Hooking MessageBox using VBA in Excel:

Option Explicit
 
' Import
Private Declare Function UnhookWindowsHookEx Lib "user32" _
    (ByVal hHook As Long) As Long
 
Private Declare Function GetCurrentThreadId Lib "kernel32" () As Long
 
Private Declare Function SetWindowsHookEx Lib "user32" _
    Alias "SetWindowsHookExA" _
    (ByVal idHook As Long, _
     ByVal lpfn As Long, _
     ByVal hmod As Long, _
     ByVal dwThreadId As Long) As Long
 
Private Declare Function SetWindowPos Lib "user32" _
    (ByVal hwnd As Long, _
     ByVal hWndInsertAfter As Long, _
     ByVal x As Long, _
     ByVal y As Long, _
     ByVal cx As Long, _
     ByVal cy As Long, _
     ByVal wFlags As Long) As Long
 
' Handle to the Hook procedure
Private hHook As Long
 
' Position
Private msgbox_x As Long
Private msgbox_y As Long
 
' Hook type
Private Const WH_CBT = 5
Private Const HCBT_ACTIVATE = 5
 
' SetWindowPos Flags
Private Const SWP_NOSIZE = &H1      ' Retains the current size
Private Const SWP_NOZORDER = &H4    ' Retains the current Z order

Sub TestMsgBox()
    MsgBoxPos "Set non-Center Position", _
              vbOKOnly, _
              "Message Box Hooking", _
              400, 300
End Sub
 
Public Sub MsgBoxPos(strPromt As String, _
              vbButtons As VbMsgBoxStyle, _
              strTitle As String, _
              xPos As Long, _
              yPos As Long)
 
    ' Store position
    msgbox_x = xPos
    msgbox_y = yPos
 
    ' Set Hook
    hHook = SetWindowsHookEx(WH_CBT, _
                              AddressOf MsgBoxHookProc, _
                              0, _
                              GetCurrentThreadId)
 
    ' Run MessageBox
    MsgBox strPromt, vbButtons, strTitle
End Sub
 
Private Function MsgBoxHookProc(ByVal lMsg As Long, _
                                ByVal wParam As Long, _
                                ByVal lParam As Long) As Long
    If lMsg = HCBT_ACTIVATE Then
        ' Change position
        SetWindowPos wParam, 0, msgbox_x, msgbox_y, _
                     0, 0, SWP_NOSIZE + SWP_NOZORDER
 
        ' Release the Hook
        UnhookWindowsHookEx hHook
    End If
 
    MsgBoxHookProc = False
End Function

Using Message Box (MsgBox) in Excel VBA

Excel Trick — Wed, 08 Apr 2009 14:06:06 +0000

MsgBox function in VBA displays a message in a window and waits for click on a button.

Example of using Yes-No Message Box:

Sub MessageBoxExample()
    Dim iRet As Integer
    Dim strPrompt As String
    Dim strTitle As String
 
    ' Promt
    strPrompt = "Ask Your Question Here, OK?"
 
    ' Dialog's Title
    strTitle = "My Tite"
 
    'Display MessageBox
    iRet = MsgBox(strPrompt, vbYesNo, strTitle)
 
    ' Check pressed button
    If iRet = vbNo Then
        MsgBox "NO!"
    Else
        MsgBox "Yes!"
    End If
End Sub

Message Box returns an integer value to indicate clicked button (Yes, No, Cancel, etc.):

Return Values
1	OK	vbOk
2	Cancel	vbCancel
3	Abort	vbAbort
4	Retry	vbRetry
5	Ignore	vbIgnore
6	Yes	vbYes
7	No	vbNo

You can specify the number and type of buttons of Message Box (the default value for buttons is 0 - display OK button only):

Type of Buttons
0	vbOKOnly	OK button only
1	vbOKCancel	OK and Cancel buttons
2	vbAbortRetryIgnore	Abort, Retry, and Ignore buttons
3	vbYesNoCancel	Yes, No, and Cancel buttons
4	vbYesNo	Yes and No buttons
5	vbRetryCancel	Retry and Cancel buttons

Using Intersection to Create a Range in Excel VBA

Excel Trick — Wed, 08 Apr 2009 13:11:40 +0000

Intersect Method returns a Range object that represents the Intersection of Ranges.

Example selects the Intersection of 2 Ranges (A1:D5 and C3:C10). If the Intersection is blank, the example displays a message box:

Private Sub UseIntersection()
    IntersectRanges Range("A1:D5"), Range("C3:C10")
End Sub
 
Private Sub IntersectRanges(range1 As Range, range2 As Range)
    Dim intRange As Range
 
    ' Application.Intersect Method
    Set intRange = Application.Intersect(range1, range2)
 
    If intRange Is Nothing Then
        ' No Intersection
        MsgBox "Ranges Do Not Intersect!"
    Else
        ' Show new Range's address
        MsgBox (intRange.Address)
 
        ' Select new Range
        intRange.Select
    End If
End Sub

Range Object in VBA

Excel Trick — Fri, 27 Mar 2009 13:53:05 +0000

The Range Object is the object you will use most within your Excel VBA. Before you can manipulate any region within Excel, you must express it as a Range object:

Dim myRange As Range
Set myRange = ActiveSheet.Range("A1")

and work with methods and properties of that range:

myRange.Delete Shift:=xlUp

A Range object represents a cell, a row, a column, a selection of cells containing one or more blocks of cells or even a group of cells on multiple sheets:

' Cells
Set myRange = ActiveSheet.Range("A1:D5")
 
' Row
Set myRange = ActiveSheet.Rows(1)
 
' Column
Set myRange = ActiveSheet.Columns(2)
 
' Group of Cells
Set myRange = Application.Union( _ 
    ActiveSheet.Range("A1:D1"), _
    ActiveSheet.Range("C3:C5"))
 
' Select method
myRange.Select

How To Store Current Range Selection using VBA in Excel?

Excel Trick — Fri, 20 Mar 2009 15:38:02 +0000

Q. How To Store Current Selection using VBA in Excel?

A. Use the foloowing VBA script:

Option Explicit
Private Sub Example()
    Dim ActSheet As Worksheet
    Dim SelRange As Range
 
    Set ActSheet = ActiveSheet
    Set SelRange = Selection
 
    '' Any code here
    'Dim NewSheet As Worksheet
    '
    'ActiveSheet.Range("A1").Select
    '
    'Set NewSheet = ThisWorkbook.Sheets().Add()
    'NewSheet.Move After:=Sheets(ThisWorkbook.Sheets().Count)

    ActSheet.Select
    SelRange.Select
End Sub

Let’s discuss how it works. First, force explicit declaration of all variables:

Option Explicit

To store selection we need two variables (Worksheet and Range):

Dim ActSheet As Worksheet
Dim SelRange As Range

Then we store active Worksheet and current range selection:

Set ActSheet = ActiveSheet
Set SelRange = Selection

Now we can use any VBA code (add new sheets, select or hide cells etc) and then restore origin selection:

ActSheet.Select
SelRange.Select

Option Explicit Statement in VBA

Excel Trick — Thu, 19 Mar 2009 14:02:15 +0000

Q. How to avoid incorrectly typing the name of an existing variable?

A. Use Option Explicit statement at file level to force explicit declaration of all variables in the script:

Option Explicit

Option Explicit statement must appear in a script before any procedures.

When you use the Option Explicit statement, you must explicitly declare all variables using the Dim, Private, Public, or ReDim statements. If you attempt to use an undeclared variable name, an error occurs:

Dim myVar
myVar = 1
myNewVar = 0	' ERROR: Variable not defined.

Save Workbook as New File using VBA in Excel

Excel Trick — Tue, 17 Mar 2009 09:32:20 +0000

Q. How Save Workbook as New File?

A. Use the following VBA code:

Private Sub SaveWorkbookAsNewFile(NewFileName As String)
    Dim ActSheet As Worksheet
    Dim ActBook As Workbook
    Dim CurrentFile As String
    Dim NewFileType As String
    Dim NewFile As String
 
    Application.ScreenUpdating = False    ' Prevents screen refreshing.
    
    CurrentFile = ThisWorkbook.FullName
 
    NewFileType = "Excel Files 1997-2003 (*.xls), *.xls," & _
               "Excel Files 2007 (*.xlsx), *.xlsx," & _
               "All files (*.*), *.*"
 
    NewFile = Application.GetSaveAsFilename( _
        InitialFileName:=NewFileName, _
        fileFilter:=NewFileType)
 
    If NewFile <> "" And NewFile <> "False" Then
        ActiveWorkbook.SaveAs Filename:= NewFile, _
            FileFormat:=xlNormal, _
            Password:="", _
            WriteResPassword:="", _
            ReadOnlyRecommended:=False, _
            CreateBackup:=False
 
        Set ActBook = ActiveWorkbook
        Workbooks.Open CurrentFile
        ActBook.Close
    End If
 
    Application.ScreenUpdating = True
End Sub

How does it work? Let’s look inside.

First, turn off screen updating:

Application.ScreenUpdating = False

Store the opened file full path:

CurrentFile = ThisWorkbook.FullName

Open window to choose new filename and folder:

NewFile = Application.GetSaveAsFilename( _
    InitialFileName:=NewFileName, _
    fileFilter:=NewFileType)

And now save file as new Workbook:

ActiveWorkbook.SaveAs Filename:= NewFile, _
    FileFormat:=xlNormal, _
    Password:="", _
    WriteResPassword:="", _
    ReadOnlyRecommended:=False, _
    CreateBackup:=False

We have to close new file and open the origin workbook:

Set ActBook = ActiveWorkbook
Workbooks.Open CurrentFile
ActBook.Close

and turn on screen updating:

Application.ScreenUpdating = True